mirror of
https://git.hardenedbsd.org/hardenedbsd/HardenedBSD.git
synced 2024-11-22 03:04:34 +01:00
3e76d05231
Currently these sections are not used but defined only for amd64 and i386. Added them for all other platforms to keep all platforms in sync. There should be no functional change. This change is extracted from a bigger patch [1] of hselasky, with additional fix for the order of .fini_array section. 1. https://reviews.freebsd.org/D40467 Obtained from: hselasky MFC after: 1 week Differential Revision: https://reviews.freebsd.org/D45214
144 lines
4.0 KiB
Plaintext
144 lines
4.0 KiB
Plaintext
OUTPUT_FORMAT("elf32-powerpc-freebsd", "elf32-powerpc-freebsd",
|
|
"elf32-powerpc-freebsd")
|
|
OUTPUT_ARCH(powerpc)
|
|
ENTRY(__start)
|
|
SEARCH_DIR(/usr/lib);
|
|
PROVIDE (__stack = 0);
|
|
PHDRS
|
|
{
|
|
kernel PT_LOAD;
|
|
dynamic PT_DYNAMIC;
|
|
}
|
|
SECTIONS
|
|
{
|
|
/* Read-only sections, merged into text segment: */
|
|
|
|
. = kernbase + SIZEOF_HEADERS;
|
|
PROVIDE (begin = . - SIZEOF_HEADERS);
|
|
|
|
.text :
|
|
{
|
|
*(.glink)
|
|
*(.text)
|
|
*(.stub)
|
|
/* .gnu.warning sections are handled specially by elf32.em. */
|
|
*(.gnu.warning)
|
|
*(.gnu.linkonce.t*)
|
|
} :kernel =0
|
|
_etext = .;
|
|
PROVIDE (etext = .);
|
|
|
|
.interp : { *(.interp) }
|
|
.hash : { *(.hash) }
|
|
.dynsym : { *(.dynsym) }
|
|
.dynstr : { *(.dynstr) }
|
|
.gnu.version : { *(.gnu.version) }
|
|
.gnu.version_d : { *(.gnu.version_d) }
|
|
.gnu.version_r : { *(.gnu.version_r) }
|
|
.rela.text :
|
|
{ *(.rela.text) *(.rela.gnu.linkonce.t*) }
|
|
.rela.data :
|
|
{ *(.rela.data) *(.rela.gnu.linkonce.d*) }
|
|
.rela.rodata :
|
|
{ *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
|
|
.rela.got : { *(.rela.got) }
|
|
.rela.got1 : { *(.rela.got1) }
|
|
.rela.got2 : { *(.rela.got2) }
|
|
.rela.ctors : { *(.rela.ctors) }
|
|
.rela.dtors : { *(.rela.dtors) }
|
|
.rela.init : { *(.rela.init) }
|
|
.rela.fini : { *(.rela.fini) }
|
|
.rela.bss : { *(.rela.bss) }
|
|
.rela.plt : { *(.rela.plt) }
|
|
.rela.sdata : { *(.rela.sdata) }
|
|
.rela.sbss : { *(.rela.sbss) }
|
|
.rela.sdata2 : { *(.rela.sdata2) }
|
|
.rela.sbss2 : { *(.rela.sbss2) }
|
|
|
|
.init : { *(.init) } =0
|
|
.fini : { *(.fini) } =0
|
|
.rodata : { *(.rodata) *(.gnu.linkonce.r*) }
|
|
.rodata1 : { *(.rodata1) }
|
|
.note.gnu.build-id : {
|
|
PROVIDE (__build_id_start = .);
|
|
*(.note.gnu.build-id)
|
|
PROVIDE (__build_id_end = .);
|
|
}
|
|
.sdata2 : { *(.sdata2) }
|
|
.sbss2 : { *(.sbss2) }
|
|
/* Adjust the address for the data segment to the next page up. */
|
|
. = ((. + 0x1000) & ~(0x1000 - 1));
|
|
.data :
|
|
{
|
|
*(.data)
|
|
*(.gnu.linkonce.d*)
|
|
CONSTRUCTORS
|
|
}
|
|
.data1 : { *(.data1) }
|
|
.got1 : { *(.got1) }
|
|
. = ALIGN(4096);
|
|
.got : { *(.got) }
|
|
.got.plt : { *(.got.plt) }
|
|
.init_array :
|
|
{
|
|
PROVIDE_HIDDEN (__init_array_start = .);
|
|
KEEP (*(SORT_BY_INIT_PRIORITY(.init_array.*)))
|
|
KEEP (*(.init_array))
|
|
PROVIDE_HIDDEN (__init_array_end = .);
|
|
}
|
|
.fini_array :
|
|
{
|
|
PROVIDE_HIDDEN (__fini_array_start = .);
|
|
KEEP (*(SORT_BY_INIT_PRIORITY(.fini_array.*)))
|
|
KEEP (*(.fini_array))
|
|
PROVIDE_HIDDEN (__fini_array_end = .);
|
|
}
|
|
.dynamic : { *(.dynamic) } :kernel :dynamic
|
|
/* Put .ctors and .dtors next to the .got2 section, so that the pointers
|
|
get relocated with -mrelocatable. Also put in the .fixup pointers.
|
|
The current compiler no longer needs this, but keep it around for 2.7.2 */
|
|
PROVIDE (_GOT2_START_ = .);
|
|
.got2 : { *(.got2) } :kernel
|
|
PROVIDE (__CTOR_LIST__ = .);
|
|
.ctors : { *(.ctors) }
|
|
PROVIDE (__CTOR_END__ = .);
|
|
PROVIDE (__DTOR_LIST__ = .);
|
|
.dtors : { *(.dtors) }
|
|
PROVIDE (__DTOR_END__ = .);
|
|
PROVIDE (_FIXUP_START_ = .);
|
|
.fixup : { *(.fixup) }
|
|
PROVIDE (_FIXUP_END_ = .);
|
|
PROVIDE (_GOT2_END_ = .);
|
|
/* We want the small data sections together, so single-instruction offsets
|
|
can access them all, and initialized data all before uninitialized, so
|
|
we can shorten the on-disk segment size. */
|
|
.sdata : { *(.sdata) }
|
|
_edata = .;
|
|
PROVIDE (edata = .);
|
|
.sbss :
|
|
{
|
|
PROVIDE (__sbss_start = .);
|
|
*(.sbss)
|
|
*(.scommon)
|
|
*(.dynsbss)
|
|
PROVIDE (__sbss_end = .);
|
|
}
|
|
.plt : { *(.plt) }
|
|
.bss :
|
|
{
|
|
PROVIDE (__bss_start = .);
|
|
*(.dynbss)
|
|
*(.bss)
|
|
*(COMMON)
|
|
}
|
|
_end = . ;
|
|
PROVIDE (end = .);
|
|
|
|
/* Debug */
|
|
INCLUDE debuginfo.ldscript
|
|
|
|
.gnu.attributes 0 : { KEEP (*(.gnu.attributes)) }
|
|
/DISCARD/ : { *(.note.GNU-stack) }
|
|
}
|
|
|